1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
/////////////////////////////////////////////////////////////////////////
// Copyright (c) 2011-2016 by Simon Schneegans
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or (at
// your option) any later version.
//
// This program is distributed in the hope that it will be useful, but
// WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
// General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <http://www.gnu.org/licenses/>.
/////////////////////////////////////////////////////////////////////////
namespace GnomePie {
/////////////////////////////////////////////////////////////////////////
/// A group of Actions, which represent the users gtk-bookmarks, his home
/// directory, desktop and trash. It stay up-to-date, even if the
/// bookmarks change.
/////////////////////////////////////////////////////////////////////////
public class BookmarkGroup : ActionGroup {
/////////////////////////////////////////////////////////////////////
/// Used to register this type of ActionGroup. It sets the display
/// name for this ActionGroup, it's icon name and the string used in
/// the pies.conf file for this kind of ActionGroups.
/////////////////////////////////////////////////////////////////////
public static GroupRegistry.TypeDescription register() {
var description = new GroupRegistry.TypeDescription();
description.name = _("Group: Bookmarks");
description.icon = "user-bookmarks";
description.description = _("Shows a Slice for each of your directory Bookmarks.");
description.id = "bookmarks";
return description;
}
/////////////////////////////////////////////////////////////////////
/// Two members needed to avoid useless, frequent changes of the
/// stored Actions.
/////////////////////////////////////////////////////////////////////
private bool changing = false;
private bool changed_again = false;
/////////////////////////////////////////////////////////////////////
/// C'tor, initializes all members.
/////////////////////////////////////////////////////////////////////
public BookmarkGroup(string parent_id) {
GLib.Object(parent_id : parent_id);
}
/////////////////////////////////////////////////////////////////////
/// Construct block loads the bookmarks of the user and adds a file
/// monitor in order to update the BookmarkGroup when the bookmarks
/// of the user change.
/////////////////////////////////////////////////////////////////////
construct {
this.load();
// add monitor
var bookmark_file = GLib.File.new_for_path(
GLib.Environment.get_home_dir()).get_child(".gtk-bookmarks");
if (bookmark_file.query_exists()) {
try {
var monitor = bookmark_file.monitor(GLib.FileMonitorFlags.NONE);
monitor.changed.connect(this.reload);
} catch (GLib.Error e) {
warning(e.message);
}
}
}
/////////////////////////////////////////////////////////////////////
/// Adds Actions for each gtk-bookmark of the user and for his home
/// folder, desktop and trash.
/////////////////////////////////////////////////////////////////////
private void load() {
// add home folder
this.add_action(ActionRegistry.new_for_uri("file://" + GLib.Environment.get_home_dir()));
// add .gtk-bookmarks
var bookmark_file = GLib.File.new_for_path(
GLib.Environment.get_home_dir()).get_child(".gtk-bookmarks");
if (!bookmark_file.query_exists()) {
warning("Failed to find file \".gtk-bookmarks\"!");
return;
}
try {
var dis = new DataInputStream(bookmark_file.read());
string line;
while ((line = dis.read_line(null)) != null) {
var parts = line.split(" ");
string uri = parts[0];
string name = parts[1];
this.add_action(ActionRegistry.new_for_uri(uri, name));
}
} catch (Error e) {
error ("%s", e.message);
}
// add trash
this.add_action(ActionRegistry.new_for_uri("trash://"));
// add desktop
this.add_action(ActionRegistry.new_for_uri("file://" + GLib.Environment.get_user_special_dir(GLib.UserDirectory.DESKTOP)));
}
/////////////////////////////////////////////////////////////////////
/// Reloads all Bookmarks. Is called when the user's gtk-bookmarks
/// file changes.
/////////////////////////////////////////////////////////////////////
private void reload() {
// avoid too frequent changes...
if (!this.changing) {
this.changing = true;
Timeout.add(200, () => {
if (this.changed_again) {
this.changed_again = false;
return true;
}
// reload
message("Bookmarks changed...");
this.delete_all();
this.load();
this.changing = false;
return false;
});
} else {
this.changed_again = true;
}
}
}
}
|
