1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
/*
Copyright (c) 2011 by Simon Schneegans
This program is free software: you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the Free
Software Foundation, either version 3 of the License, or (at your option)
any later version.
This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
more details.
You should have received a copy of the GNU General Public License along with
this program. If not, see <http://www.gnu.org/licenses/>.
*/
namespace GnomePie {
/////////////////////////////////////////////////////////////////////
/// An ActionGroup which contains all currently plugged-in devices,
/// such as CD-ROM's or USB-sticks.
/////////////////////////////////////////////////////////////////////
public class DevicesGroup : ActionGroup {
/////////////////////////////////////////////////////////////////////
/// Used to register this type of ActionGroup. It sets the display
/// name for this ActionGroup, it's icon name and the string used in
/// the pies.conf file for this kind of ActionGroups.
/////////////////////////////////////////////////////////////////////
public static void register(out string name, out string icon, out string settings_name) {
name = _("Devices");
icon = "harddrive";
settings_name = "devices";
}
/////////////////////////////////////////////////////////////////////
/// Two members needed to avoid useless, frequent changes of the
/// stored Actions.
/////////////////////////////////////////////////////////////////////
private bool changing = false;
private bool changed_again = false;
/////////////////////////////////////////////////////////////////////
/// The VolumeMonitor used to check for added or removed devices.
/////////////////////////////////////////////////////////////////////
private GLib.VolumeMonitor monitor;
/////////////////////////////////////////////////////////////////////
/// C'tor, initializes all members.
/////////////////////////////////////////////////////////////////////
public DevicesGroup(string parent_id) {
GLib.Object(parent_id : parent_id);
}
/////////////////////////////////////////////////////////////////////
/// Construct block loads all currently plugged-in devices and
/// connects signal handlers to the VolumeMonitor.
/////////////////////////////////////////////////////////////////////
construct {
this.monitor = GLib.VolumeMonitor.get();
this.load();
// add monitor
this.monitor.mount_added.connect(this.reload);
this.monitor.mount_removed.connect(this.reload);
}
/////////////////////////////////////////////////////////////////////
/// Loads all currently plugged-in devices.
/////////////////////////////////////////////////////////////////////
private void load() {
// add root device
this.add_action(new UriAction(_("Root"), "harddrive", "file:///"));
// add all other devices
foreach(var mount in this.monitor.get_mounts()) {
// get icon
var icon_names = mount.get_icon().to_string().split(" ");
string icon = "";
foreach (var icon_name in icon_names) {
if (Gtk.IconTheme.get_default().has_icon(icon_name)) {
icon = icon_name;
break;
}
}
this.add_action(new UriAction(mount.get_name(), icon, mount.get_root().get_uri()));
}
}
/////////////////////////////////////////////////////////////////////
/// Reloads all devices. Is called when the VolumeMonitor changes.
/////////////////////////////////////////////////////////////////////
private void reload() {
// avoid too frequent changes...
if (!this.changing) {
this.changing = true;
Timeout.add(200, () => {
if (this.changed_again) {
this.changed_again = false;
return true;
}
// reload
message("Devices changed...");
this.delete_all();
this.load();
this.changing = false;
return false;
});
} else {
this.changed_again = true;
}
}
}
}
|
