1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
|
/////////////////////////////////////////////////////////////////////////
// Copyright 2011-2018 Simon Schneegans
//
// Permission is hereby granted, free of charge, to any person obtaining
// a copy of this software and associated documentation files (the
// "Software"), to deal in the Software without restriction, including
// without limitation the rights to use, copy, modify, merge, publish,
// distribute, sublicense, and/or sell copies of the Software, and to
// permit persons to whom the Software is furnished to do so, subject to
// the following conditions:
//
// The above copyright notice and this permission notice shall be
// included in all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
// EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
// MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
// IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
// CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
// TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
// SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
/////////////////////////////////////////////////////////////////////////
using GLib.Math;
namespace GnomePie {
/////////////////////////////////////////////////////////////////////////
/// Renders the center of a Pie.
/////////////////////////////////////////////////////////////////////////
public class CenterRenderer : GLib.Object {
/////////////////////////////////////////////////////////////////////
/// The PieRenderer which owns this CenterRenderer.
/////////////////////////////////////////////////////////////////////
private unowned PieRenderer parent;
/////////////////////////////////////////////////////////////////////
/// The caption drawn in the center. Changes when the active slice
/// changes.
/////////////////////////////////////////////////////////////////////
private unowned Image? caption;
/////////////////////////////////////////////////////////////////////
/// The color of the currently active slice. Used to colorize layers.
/////////////////////////////////////////////////////////////////////
private Color color;
/////////////////////////////////////////////////////////////////////
/// Two AnimatedValues: alpha is for global transparency (when
/// fading in/out), activity is 1.0 if there is an active slice and
/// 0.0 if there is no active slice.
/////////////////////////////////////////////////////////////////////
private AnimatedValue activity;
private AnimatedValue alpha;
/////////////////////////////////////////////////////////////////////
/// C'tor, initializes all members.
/////////////////////////////////////////////////////////////////////
public CenterRenderer(PieRenderer parent) {
this.parent = parent;
this.activity = new AnimatedValue.linear(0.0, 0.0, Config.global.theme.transition_time);
this.alpha = new AnimatedValue.linear(0.0, 1.0, Config.global.theme.fade_in_time);
this.color = new Color();
this.caption = null;
}
/////////////////////////////////////////////////////////////////////
/// Initiates the fade-out animation by resetting the targets of the
/// AnimatedValues to 0.0.
/////////////////////////////////////////////////////////////////////
public void fade_out() {
this.activity.reset_target(0.0, Config.global.theme.fade_out_time);
this.alpha.reset_target(0.0, Config.global.theme.fade_out_time);
}
/////////////////////////////////////////////////////////////////////
/// Should be called if the active slice of the PieRenderer changes.
/// The members activity, caption and color are set accordingly.
/////////////////////////////////////////////////////////////////////
public void set_active_slice(SliceRenderer? active_slice) {
if (active_slice == null) {
this.activity.reset_target(0.0, Config.global.theme.transition_time);
} else {
this.activity.reset_target(1.0, Config.global.theme.transition_time);
this.caption = active_slice.caption;
this.color = active_slice.color;
}
}
/////////////////////////////////////////////////////////////////////
/// Draws all center layers and the caption.
/////////////////////////////////////////////////////////////////////
public void draw(double frame_time, Cairo.Context ctx, double angle, int slice_track) {
// get all center_layers
var layers = Config.global.theme.center_layers;
// update the AnimatedValues
this.activity.update(frame_time);
this.alpha.update(frame_time);
// draw each layer
foreach (var layer in layers) {
ctx.save();
// calculate all values needed for animation/drawing
double max_scale = layer.active_scale*this.activity.val
+ layer.inactive_scale*(1.0-this.activity.val);
double max_alpha = layer.active_alpha*this.activity.val
+ layer.inactive_alpha*(1.0-this.activity.val);
double colorize = ((layer.active_colorize == true) ? this.activity.val : 0.0)
+ ((layer.inactive_colorize == true) ? 1.0 - this.activity.val : 0.0);
double max_rotation_speed = layer.active_rotation_speed*this.activity.val
+ layer.inactive_rotation_speed*(1.0-this.activity.val);
CenterLayer.RotationMode rotation_mode = ((this.activity.val > 0.5) ?
layer.active_rotation_mode : layer.inactive_rotation_mode);
double direction = 0;
if (rotation_mode == CenterLayer.RotationMode.TO_MOUSE) {
direction = angle;
} else if (rotation_mode == CenterLayer.RotationMode.TO_ACTIVE) {
double slice_angle = parent.total_slice_count > 0 ? 2*PI/parent.total_slice_count : 0;
direction = (int)((angle+0.5*slice_angle) / (slice_angle))*slice_angle;
} else if (rotation_mode == CenterLayer.RotationMode.TO_SECOND) {
var now = new DateTime.now_local();
direction = 2*PI*(now.get_second()+60-15)/60;
} else if (rotation_mode == CenterLayer.RotationMode.TO_MINUTE) {
var now = new DateTime.now_local();
direction = 2*PI*(now.get_minute()+60-15)/60;
} else if (rotation_mode == CenterLayer.RotationMode.TO_HOUR_24) {
var now = new DateTime.now_local();
direction = 2*PI*(now.get_hour()+24-6)/24 + 2*PI*(now.get_minute())/(60*24);
} else if (rotation_mode == CenterLayer.RotationMode.TO_HOUR_12) {
var now = new DateTime.now_local();
direction = 2*PI*(now.get_hour()+12-3)/12 + 2*PI*(now.get_minute())/(60*12);
}
if (rotation_mode == CenterLayer.RotationMode.AUTO) {
layer.rotation += max_rotation_speed*frame_time;
} else {
direction = Math.fmod(direction, 2*PI);
double diff = direction-layer.rotation;
double smoothy = fabs(diff) < 0.9 ? fabs(diff) + 0.1 : 1.0;
double step = max_rotation_speed*frame_time*smoothy;
if (fabs(diff) <= step || fabs(diff) >= 2.0*PI - step)
layer.rotation = direction;
else {
if ((diff > 0 && diff < PI) || diff < -PI) layer.rotation += step;
else layer.rotation -= step;
}
}
layer.rotation = fmod(layer.rotation+2*PI, 2*PI);
if (colorize > 0.0) ctx.push_group();
// transform the context
ctx.rotate(layer.rotation);
ctx.scale(max_scale, max_scale);
// paint the layer
layer.image.paint_on(ctx, this.alpha.val*max_alpha);
// colorize it, if necessary
if (colorize > 0.0) {
ctx.set_operator(Cairo.Operator.ATOP);
ctx.set_source_rgb(this.color.r, this.color.g, this.color.b);
ctx.paint_with_alpha(colorize);
ctx.set_operator(Cairo.Operator.OVER);
ctx.pop_group_to_source();
ctx.paint();
}
ctx.restore();
}
// draw caption
if (Config.global.theme.caption && caption != null && this.activity.val > 0) {
ctx.save();
double x, y;
ctx.get_current_point(out x, out y);
ctx.move_to(GLib.Math.floor(x), GLib.Math.floor(y));
caption.paint_on(ctx, this.activity.val*this.alpha.val);
ctx.restore();
}
//scroll pie
if (this.alpha.val > 0.1
&& this.parent.original_visible_slice_count < this.parent.slice_count()
&& this.parent.original_visible_slice_count > 0) {
int np= (this.parent.slice_count()+this.parent.original_visible_slice_count -1)/this.parent.original_visible_slice_count;
int cp= this.parent.first_slice_idx / this.parent.original_visible_slice_count;
int r= 8; //circle radious
int dy= 20; //distance between circles
double a= 0.8 * this.alpha.val;
int dx= (int)Config.global.theme.center_radius + r + 10;
if (this.parent.center_x + dx > this.parent.size_w)
dx= -dx; //no right side, put scroll in the left size
ctx.save();
ctx.identity_matrix();
ctx.translate(this.parent.center_x + dx, this.parent.center_y - (np-1)*dy/2);
for (int i=0; i<np; i++) {
ctx.arc( 0, 0, r, 0, 2*PI );
if (i == cp){
ctx.set_source_rgba(0.3,0.3,0.3, a); //light gray stroke
ctx.stroke_preserve();
ctx.set_source_rgba(1,1,1, a); //white fill
ctx.fill(); //current
} else {
ctx.set_source_rgba(1,1,1, a); //white stroke
ctx.stroke_preserve();
ctx.set_source_rgba(0.3,0.3,0.3, a/4); //light gray fill
ctx.fill(); //current
}
ctx.translate(0, dy);
}
ctx.restore();
}
}
}
}
|
